How to...

The io.Connect COM library allows you to interop-enable your MS Office VBA apps and integrate them with other interop-enabled apps in io.Connect Desktop. You can use io.Connect functionality in your VBA apps for Excel, Outlook, Word, etc. The io.Connect COM library support the 32-bit and 64-bit versions of MS Office 2013 and up.

To access io.Connect functionalities in your VBA app, you have to reference and initialize the io.Connect COM library. The io.Connect COM library is distributed as a DLL file which is a part of the SDK bundle of io.Connect Desktop located in the %LocalAppData%/interop.io/io.Connect Desktop/SDK/GlueCOM folder.

In the io.Connect VBA Concepts section below you will find general concepts that apply when using the io.Connect COM library in VBA. The COM/VBA Reference section provides reference documentation specific to using the io.Connect COM library in VBA apps.

Referencing

The io.Connect COM library is available as a package in NuGet which you can include in your projects. The io.Connect COM library is also distributed with io.Connect Desktop and is usually located in the %LocalAppData%/interop.io/io.Connect Desktop/SDK/GlueCOMv2 folder.

To reference the io.Connect COM library, open the Microsoft VBA Editor and go to Tools > References. Click "Browse" find and select the GlueCOM.dll file. In the list of available references you should now see "Tick42 Glue for COM":

Initialization

To initialize the io.Connect COM library, import the library and create an instance of the Glue42 class. You can use this instance to access all io.Connect functionality. Finally, register your app.

Below is an example of a subroutine which initializes io.Connect, exposing the app instance under the name "My VBA App":

Dim Glue As Glue42

Public Sub InitializeGlue()
    If Glue Is Nothing Then
        Set Glue = New Glue42
        ' Connecting to io.Connect and registering the app instance.
        Glue.StartWithAppName ("My VBA App")
    End If
End Sub

Once the io.Connect COM library has been initialized, your app has access to all io.Connect functionalities. For more detailed information on the different io.Connect capabilities and APIs, see:

• Shared Contexts
• Channels
• Interop
• Window Management

The following sections explain concepts related to using the io.Connect COM library.

Composite Values

All io.Connect functionality related to receiving and sending data works with composite data values (structures). The io.Connect COM library for VBA provides a mechanism based on the GlueDynamicValue class to dynamically build composite values and to access individual fields within the composite structure.

Building Composite Values

• use CreateGlueValues to get an empty dynamic value representing the root of the composite data structure;
• use chained indexing to set individual fields within the data structure (see Indexing);

The following shows how to build a sample composite value which can be used as an argument when invoking an Interop method:

' Creating an empty root value.
Dim MyVal
Set MyVal = Glue.CreateGlueValues

' Setting a field with a string value.
MyVal("operation") = "AddSub"

' Setting a field with an array of integers as a value.
Dim OperandsArray(0 To 1) As Integer
OperandsArray(0) = 5
OperandsArray(1) = 3
MyVal("operands") = OperandsArray

' Setting a string field nested in another composite value.
MyVal("metadata")("reason") = "testing"

As a result, MyVal will contain the following composite value (represented as a JSON object):

{
    "operation": "AddSub",
    "operands": [5, 3],
    "metadata": {
        "reason": "testing"
    }
}

Indexing

You can use named indexing with instances of GlueDynamicValue to access child nodes by name.

For example:

Dim MyValue
MyValue = DynamicValue("ChildNodeName")

Depending on whether "ChildNodeName" exists and its type, the return value from the named indexing can be:

• Variant/GlueDynamicValue if "ChildNodeName" represents a composite value. If "ChildNodeName" doesn't exist, it will be automatically created as an empty composite value.
• Variant/<some native type> if "ChildNodeName" represents an elementary field.

As indexing can return another instance of GlueDynamicValue, this allows for chained indexing to access nested composite values:

Dim MyDoubleValue as Double
MyDoubleValue = DynamicValue("CompositeLevel_0")("CompositeLevel_1")("ElementaryDoubleField")

⚠️ Note that using indexing is recommended only when accessing fields within a composite value with a known structure.

Accessing Composite Value Fields

• use the GetReflectData method of a data provider instance passing an empty string as an argument to get the root of the composite value;
• the data provider is typically passed as an argument to callback/event handler subroutines which are invoked when io.Connect sends data to the app;

The example below uses the same data structure from the previous example and shows how to access fields in a composite value. The invocationRequest data provider is passed as an argument to the handler subroutine:

' Declaring the native variables.
Dim Operation As String
Dim Operand1, Operand2 As Integer
Dim Reason As String
Dim Error As Integer

' Getting the root of the composite value from the data provider.
Dim Args
Set Args = invocationRequest.GetReflectData("")

' Extracting the elementary fields from the composite value:

' Accessing a string value.
Operation = Args("operation")
' Accessing integer values in an array.
Operand1 = Args("operands")(0)
Operand2 = Args("operands")(1)
' Access a string value inside a composite value.
Reason = Args("metadata")("reason")
' This will raise a "Type Mismatch" exception: "metadata" is a composite value which can't be cast to "Integer".
Error = Args("metadata")

Elementary fields are automatically cast to the compatible native type. Trying to assign to an incompatible type will raise an exception. Array elements can be accessed by their numeric index. Arrays can't be directly cast to a native array type. Accessing a field which doesn't exist will return an empty GlueDynamicValue.

You can also store a lower-level composite value or array in a temporary variable and use it to access its fields. This helps avoid unnecessary repetitions of the path to deeper nested composite values and extra calls to the io.Connect COM library:

Dim OperArr
' Storing an array from a composite data structure in a variable.
OperArr = Args("operands")
' Accessing array elements from the temporary variable.
Operand1 = OperArr(0)
Operand2 = OperArr(1)

Another possibility for accessing a lower-level value in a composite structure directly from the data provider is to specify a path to the value when invoking GetReflectData. This can be useful when handling complex composite values where only part of the value structure is of interest:

' Accessing directly a lower-level value by providing a path as an argument.
Reason = invocationRequest.GetReflectData("metadata.reason")

Traversing Composite Values with Unknown or Dynamic Structure

To traverse and get information about the fields of a composite value with unknown or dynamic structure, use the Count, Names and Values properties of a GlueDynamicValue instance and its Contains method.

io.Connect Time

io.Connect time is essentially a Unix timestamp: the number of milliseconds since the Unix epoch, i.e. 1970-01-01 00:00:00 UTC, ignoring leap seconds. To convert from io.Connect time to VBA Date, you can use the following formula:

VBADate = CDate(GlueTime / 86400 + 25569)

• 86400 is the number of seconds in one day (60 * 60 * 24);
• 25569 is the VBA numeric representation of 1970-01-01 00:00:00;

⚠️ *Note that the resulting Date timestamp will also be in UTC, and not in local time.

Helper Functions

The VBA samples use a helper function which simplifies the use of the io.Connect COM library and/or provides functionality not directly available in VBA.

GetFormHwnd

This helper function is used to retrieve the window handle (HWND) of a VBA UserForm.

Implementation:

Private Declare PtrSafe Function FindWindowA _
    Lib "user32.dll" ( _
    ByVal lpClassName As String, _
    ByVal lpWindowName As String) As LongPtr

Public Function GetFormHwnd(Form As Variant) As Long
    Dim strCaption As String
    Dim strClass As String

    ' Class name changed in Office 2000.
    If Val(Application.Version) >= 9 Then
        strClass = "ThunderDFrame"
    Else
        strClass = "ThunderXFrame"
    End If

    Randomize
    ' Saving the caption.
    strCaption = Form.Caption
    Form.Caption = "FindMe#" + CStr(Rnd)

    GetFormHwnd = CLng(FindWindowA(strClass, Form.Caption))
    'Restoring the caption.
    Form.Caption = strCaption
End Function

This reference describes the components in the io.Connect COM library relevant to VBA.

⚠️ Note that the library also contains components that aren't intended to be directly used by VBA apps.

GlueMethodFlags

Enumeration of the possible flags associated with an io.Connect method.

GlueMethodInvocationStatus

Enumeration of the possible values for the status of an io.Connect method invocation.

GlueStreamState

Enumeration of the possible values for the status of an io.Connect stream subscription.

GlueWindowEventType

Enumeration of the possible values for the event type passed to HandleWindowEvent

⚠️ Note that not all event types are applicable to VBA apps.

GlueContext

This type is used to store information about an io.Connect context.

Properties

VBGlueInstance

This type is used to store information about an io.Connect app instance.

Properties

VBGlueMethod

This type is used to store information about an io.Connect method or stream.

Properties

VBGlueResult

This type is used to store information about the result that an io.Connect Interop method will return when invoked.

Properties

Glue42

This class is used as the main entry point for using any io.Connect functionality.

Properties

This class has no properties which can be used in VBA.

Methods

CreateDefaultVBGlueWindowSettings

Creates an instance of GlueWindowSettings which can be used to initiate window registration with specific settings. See also RegisterGlueWindowWithSettings

Signature:

Function CreateDefaultVBGlueWindowSettings() As GlueWindowSettings

Parameters: None

Return value: GlueWindowSettings

CreateGlueData

Creates an instance of GlueData containing a composite value. The returned instance can be used to initialize the GlueData property of VBGlueResult

Signature:

Function CreateGlueData(data) As GlueData

Parameters:

Return value: GlueData

CreateGlueValues

Creates an instance of GlueDynamicValue which can represent a root node in a composite value.

Signature:

Function CreateGlueValues() as Variant

Parameters: None

Return value: Variant/GlueDynamicValue

CreateMethodInvocator

Creates an instance of GlueMethodInvocator which can serve as a proxy for invoking io.Connect methods and receiving results from method invocations.

Signature:

Function CreateMethodInvocator() As GlueMethodInvocator

Parameters: None

Return value: GlueMethodInvocator

CreateServerMethod

Creates an instance of GlueServerMethod which can be used to register an io.Connect method and handle the server-side interaction with io.Connect.

Signature:

Function CreateServerMethod(methodName As String, Input As String, Output As String, objectTypesCSV As String) As GlueServerMethod

Parameters:

Return value: GlueServerMethod

CreateServerStream

Creates an instance of GlueServerStream which can be used to register an io.Connect stream and handle the server-side interaction with io.Connect.

Signature:

Function CreateServerStream(streamName As String, Input As String, Output As String, objectTypesCSV As String) As GlueServerStream

Parameters:

Return value: GlueServerStream

CreateStreamConsumer

Creates an instance of GlueStreamConsumer which can be used to subscribe to io.Connect streams and handle the client-side interaction with io.Connect.

Signature:

Function CreateStreamConsumer() As GlueStreamConsumer

Parameters: None

Return value: GlueStreamConsumer

GetChannels

Obtains the names of all available io.Connect Channels.

Signature:

Function GetChannels() As String()

Parameters: None

Return value: String()

GetGlueContext

Creates an instance of GlueContextManager which can later be linked to an io.Connect context with the Open method.

Signature:

Function GetGlueContext(contextName As String) As GlueContextManager

Parameters:

Return value: GlueContextManager

GetKnownContexts

Obtains a list of all currently available io.Connect contexts.

Signature:

Function GetKnwonContexts() As GlueContext()`

Parameters: None

Return value: GlueContext() - GlueContext array containing information about the currently available io.Connect contexts.

GetMethodNamesForTarget

Obtains the names of all io.Connect methods or streams exposed by the specified apps.

Signature:

Function GetMethodNamesForTarget(targetRegex As String) As String()

Parameters:

Return value: String()

GetTargets

Obtains the names of all io.Connect apps currently exposing methods or streams.

Signature:

Function GetTargets() As String()

Parameters: None

Return value: String()

Log

Outputs a message to the io.Connect log.

Signature:

Sub Log(level As Byte, Message As String)

Parameters:

Return value: None

RegisterGlueWindow

Initiates the registration of a VBA UserForm as an io.Connect Window with default settings.

Signature:

Function RegisterGlueWindow(hwnd As Long, windowEventHandler As IGlueWindowEventHandler) As GlueWindow

Parameters:

Return value: GlueWindow

⚠️ Note that the returned instance of GlueWindow shouldn't be used to interact with the io.Connect Window until the HandleWindowReady event has been raised (i.e., the window registration is complete).

RegisterGlueWindowWithSettings

Initiates the registration of a VBA UserForm as an io.Connect Window with custom settings.

Signature:

Function RegisterGlueWindowWithSettings(hwnd As Long, settings As GlueWindowSettings, windowEventHandler As IGlueWindowEventHandler) As GlueWindow

Parameters:

Return value: GlueWindow

⚠️ Note that the returned instance of GlueWindow shouldn't be used to interact with the io.Connect Window until the HandleWindowReady event has been raised (i.e., the window registration is complete).

StartWithAppName

Connects to the io.Connect Gateway and announces the app instance. Connection to the io.Connect Gateway is required for using any io.Connect functionality.

Signature:

Sub StartWithAppName(ApplicationName As String)

Parameters:

Return value: None

Stop

Disconnects from the io.Connect Gateway, shutting down all communication:

• The app instance will no longer receive any notifications from io.Connect, no event handlers will be invoked.
• All stream subscriptions will be terminated.
• All methods and streams published by the app will be automatically unregistered.
• The app instance will no longer be visible/discoverable.
• io.Connect context data (including io.Connect Channel data) set by the app will persist until overwritten by other apps.

Signature:

Sub Stop()

Parameters: None

Return value: None

GlueContextManager

This class is used for interaction with io.Connect contexts. Interface: IGlueContext.

Properties

This class has no properties.

Methods

Close

Closes an open io.Connect context. The context is unlinked from the GlueContextManager which can no longer be used to interact with the context. The associated event handler will no longer be executed when the context data changes.

Signature:

Sub Close()

Parameters: None

Return value: None

GetContextInfo

Obtains a GlueContext containing information about the linked context.

Signature:

Function GetContextInfo() As GlueContext

Parameters: None

Return value: GlueContext

GetDataAsJson

Gets a composite value or an elementary field in JSON format.

Signature:

Function GetDataAsJson(fieldPath As String) As String

Parameters:

Return value: String

GetReflectData

Gets a composite value or an elementary field from the associated composite value structure.

Signature:

Function GetReflectData(fieldPath As String) as Variant

Parameters:

Return value:

• Variant/GlueDynamicValue if fieldPath refers to a composite value;
• Variant/<some native type> if fieldPath refers to an elementary field;
• Variant/Empty if the specified fieldPath doesn't exist;

Open

Opens an io.Connect context. If the context doesn't exist, it is automatically created with an empty data value.

Signature:

Sub Open()

Parameters: None

Return value: None

Remove

Removes a shared context value.

Signature:

Sub Remove(fieldPath As String)

Parameters:

Return value: None

SetValue

Sets or updates a context value.

Signature:

Sub SetValue(fieldPath As String, Value)

Parameters:

Return value: None

UpdateContextDataJson

Updates a composite value or an elementary field in the shared context.

Signature:

Sub UpdateContextDataJson(fieldPath As String, jsonEncodedData As String)

Parameters:

Return value: None

Nonapplicable Methods

The following methods aren't intended to be used in VBA:

• BuildAndSetContextData
• BuildAndUpdateContextData
• GetData
• IsLaunchedByGD
• JsonToVariant
• SetContextData
• SetContextDataOnFieldPath
• UpdateContextData

Events

HandleContextUpdate

The handler for this event is executed when the linked context data has been updated or when a context has been linked with the Open method.

Handler signature:

Sub GlueContextManager_HandleContextUpdate(ByVal contextUpdate As IGlueContextUpdate)

Parameters:

Nonapplicable Events

The following events aren't intended to be used in VBA:

• HandleContext

GlueContextUpdate

An instance of this class is passed by io.Connect to the HandleContextUpdate event handler. Interface: IGlueContextUpdate.

Properties

This class has no properties.

Methods

GetContext

Obtains an instance of GlueContextManager linked to the io.Connect context that has been updated.

Signature:

Function GetContext() As GlueContextManager

Parameters: None

Return value: GlueContextManager

GlueData

This class is used to store composite data values. Interface: IGlueData.

Properties

This class has no properties.

Methods

GetReflectData

Gets a composite value or an elementary field from the associated composite value structure.

Signature:

Function GetReflectData(fieldPath As String) as Variant

Parameters:

Return value:

• Variant/GlueDynamicValue if fieldPath refers to a composite value;
• Variant/<some native type> if fieldPath refers to an elementary field;
• Variant/Empty if the specified fieldPath doesn't exist;

GlueDynamicValue

An instance of this class represents a node in a composite value. Composite values are passed to and returned by various io.Connect COM methods involving data exchange between apps. See also Building Composite Values and Accessing Composite Value Fields.

Properties

Methods

Contains

Checks if a child node with the specified name exists.

Signature:

Function Contains(Name As String) As Boolean

Parameters:

Return value: Boolean

Nonapplicable Methods

The following methods aren't intended to be used in VBA:

• GetEnumerator

GlueInvocationRequest

This class is used by apps when providing an io.Connect method implementation. An instance of this class is passed by io.Connect to the HandleInvocationRequest event handler. Interface: IGlueInvocationRequest.

Properties

Methods

GetReflectData

Gets a composite value or an elementary field from the associated composite value structure. In the case of an invocation request, this is the composite value structure holding the arguments with which the request was made.

Signature:

Function GetReflectData(fieldPath As String) as Variant

Parameters:

Return value:

• Variant/GlueDynamicValue if fieldPath refers to a composite value;
• Variant/<some native type> if fieldPath refers to an elementary field;
• Variant/Empty if the specified fieldPath doesn't exist;

SendFailure

Returns a "Failed" status to the io.Connect method invocator (caller).

Signature:

Sub SendFailure(Message As String, additionalData as Variant)

Parameters:

The following may be provided as additionalData:

Return value: None

Invoking SendFailure is equivalent to invoking SendResult with an argument of type VBGlueResult with the following properties initialized:

• Status is set to GlueMethodInvocationStatus_Failed.
• Message is set to the Message argument.
• GlueData is initialized according to the provided additionalData argument.

SendResult

Returns a result to the io.Connect method invocator (caller).

Signature:

Sub SendResult(result as Variant)

Parameters:

The following may be provided as result:

Return value: None

Below is an example of initializing a VBGlueResult for use with SendResult:

' Build the composite value to be returned to the caller.
Dim DynamicValue
Set DynamicValue = Glue.CreateGlueValues
DynamicValue("jobID") = "JOB#1234"

' Initialize the result.
Dim VBResult As VBGlueResult
VBResult.Message = "Background job started."
VBResult.Status = GlueMethodInvocationStatus_Started
Set VBResult.GlueData = Glue.CreateGlueData(DynamicValue)

' Send the result.
request.SendResult VBResult

GlueMethodInfo

This class is used to store information about an io.Connect streaming method. Instances of this class are passed as arguments to stream subscription event handlers. Interface: IGlueMethodInfo.

Properties

Methods

This class has no methods.

GlueMethodInvocator

This class is used to handle the client-side method invocation. Instances of this class can be created by using CreateMethodInvocator.

Properties

This class has no properties.

Methods

InvokeAsync

Invokes an io.Connect method asynchronously. The result is delivered via the HandleInvocationResult event.

Signature:

Sub InvokeAsync(method As String, targetRegex As String, args, all As Boolean, correlationId As String, timeoutMsecs As Long)

Parameters:

Return value: None

InvokeSync

Invokes an io.Connect method synchronously.

⚠️ Note that invoking this method will block VBA execution until the method invocation completes. As VBA code runs in a single thread, it isn't possible to synchronously invoke methods registered by the same VBA app.

Signature:

Function InvokeSync(method As String, targetRegex As String, args, all As Boolean, timeoutMsecs As Long) as VBGlueInvocationResult

Parameters:

Return value: VBGlueInvocationResult - an instance of VBGlueInvocationResult containing information about the result from the method invocation.

Events

HandleInvocationResult

The handler for this event is executed when a method invocation initiated with InvokeAsync has completed.

Handler signature:

Sub GlueMethodInvocator_HandleInvocationResult(ByVal result As IGlueInvocationResult)

Parameters:

GlueServerMethod

This class is used to expose io.Connect methods and handle the server-side interaction with io.Connect. Instances of this class can be created with CreateServerMethod. Interface: IGlueServerMethod.

Properties

Methods

Register

Registers an Interop method in io.Connect. The registered Interop method becomes visible to other io.Connect apps.

Signature:

Sub Register()

Parameters: None

Return value: None

Unregister

Unregisters an Interop method from io.Connect. The unregistered Interop method is no longer available in io.Connect.

Signature:

Sub Unregister()

Parameters: None

Return value: None

Events

HandleInvocationRequest

The handler for this event is executed when an app invokes a registered io.Connect method.

Handler signature:

Sub GlueServerMethod_HandleInvocationRequest(ByVal request As IGlueInvocationRequest)

Parameters:

GlueServerStream

This class is used to expose io.Connect streams (streaming methods) and handle the server-side interaction with io.Connect. Instances of this class can be created with CreateServerStream. Interface: IGlueServerStream.

Properties

Methods

CloseBranch

Closes a stream branch. This will disconnect (unsubscribe) all subscribers from the branch and remove the branch from the stream.

Signature:

Sub CloseBranch(branch As String)

Parameters:

Return value: None

CloseStream

Closes a stream. This will disconnect (unsubscribe) all subscribers (on all branches) from the stream. All branches will be removed from the stream.

Signature:

Sub CloseStream()

Parameters: None

Return value: None

GetBranchKeys

Gets an array containing the names of all branches of the stream.

Signature:

Function GetBranchKeys() As String()

Parameters: None

Return value: String() - an array of Strings containing the names (keys) of all stream branches.

PushVariantData

Push data to a stream or stream branch.

Signature:

Sub PushVariantData(data, branch As String)

Parameters:

Return value: None

Register

Registers an Interop stream in io.Connect. The registered stream becomes visible to other io.Connect apps.

Signature:

Sub Register()

Parameters: None

Return value: None

Unregister

Unregisters an Interop stream from io.Connect. The unregistered stream is no longer available in io.Connect.

Signature:

Sub Unregister()

Parameters: None

Return value: None

Nonapplicable Methods

The following methods aren't intended to be used in VBA:

• GatBranch
• Push

Events

HandleSubscriber

The handler for this event is executed when a new stream subscriber is accepted.

Handler signature:

Sub GlueServerStream_HandleSubscriber(ByVal subscriber As IVBGlueStreamSubscriber, ByVal requestData As IGlueData)

Parameters:

HandleSubscriberLost

The handler for this event is executed when an existing subscriber is unsubscribed from the stream.

Handler signature:

Sub GlueServerStream_HandleSubscriberLost(ByVal subscriber As IVBGlueStreamSubscriber)

Parameters:

HandleSubscriptionRequest

The handler for this event is executed when an app attempts to subscribe to a stream.

Handler signature:

Sub GlueServerStream_HandleSubscriptionRequest(ByVal request As IGlueSubscriptionRequest)

Parameters:

GlueStreamConsumer

This class is used to subscribe to io.Connect streams and handle the client-side interaction with io.Connect. Instances of this class can be created by using CreateStreamConsumer.

Properties

This class has no properties.

Methods

Subscribe

Attempt to subscribe to an io.Connect stream by sending a subscription request.

Signature:

Sub Subscribe(stream As String, targetRegex As String, args, all As Boolean, correlationId As String, timeoutMsecs As Long)

Parameters:

Return value: None

Events

HandleStreamClosed

The handler for this event is executed when the associated stream subscription has been terminated.

Handler signature:

Sub GlueStreamConsumer_HandleStreamClosed(ByVal stream As IGlueMethodInfo)

Parameters:

HandleStreamData

The handler for this event is executed when a stream publishing app pushes data to a stream.

Handler signature:

Sub GlueStreamConsumer_HandleStreamData(ByVal stream As IGlueMethodInfo, ByVal Data As IGlueData)

Parameters:

HandleStreamStatus

The handler for this event is executed when the status of the associated stream changes.

Handler signature:

Sub GlueStreamConsumer_HandleStreamStatus(ByVal stream As IGlueMethodInfo, ByVal state As GlueStreamState, ByVal Message As String, ByVal dateTime As Double)

Parameters:

HandleSubscriptionActivated

The handler for this event is executed when a subscription request has been dispatched to io.Connect. The main purpose for invoking this event is to provide an instance of the stream subscription which the app may later use to unsubscribe from the stream.

Handler signature:

Sub GlueStreamConsumer_HandleSubscriptionActivated(ByVal subscription As IGlueStreamSubscription, ByVal correlationId As String)

Parameters:

⚠️ Note that when this event is invoked, the subscription request hasn't yet been resolved.

GlueStreamSubscription

This class is used to represent an io.Connect stream subscription. Interface: IGlueStreamSubscription.

Properties

This class has no properties.

Methods

Close

Unsubscribes from the associated io.Connect stream.

Signature:

Sub Close()

Parameters: None

Return value: None

GlueSubscriptionRequest

This class is used by apps which expose io.Connect streams. An instance of this class is passed by io.Connect to the HandleSubscriptionRequest event handler. Interface: IGlueSubscriptionRequest.

Properties

Methods

Accept

Accepts a new subscriber on the stream.

Signature:

Function Accept(branch As String, result) As IGlueStreamBranch

Parameters:

Return value: IGlueStreamBranch

⚠️ Note that the return value isn't intended to be used in VBA and can be ignored.

GetReflectData

Gets a composite value or an elementary field from the associated composite value structure. In the case of a subscription request, this is the composite value structure holding the arguments with which the request was made.

Signature:

Function GetReflectData(fieldPath As String) as Variant

Parameters:

Return value:

• Variant/GlueDynamicValue if fieldPath refers to a composite value;
• Variant/<some native type> if fieldPath refers to an elementary field;
• Variant/Empty if the specified fieldPath doesn't exist;

Reject

Rejects a subscription request.

Signature:

Sub Reject(result)

Parameters:

Return value: None

GlueWindow

This class represents an io.Connect Window. Interface: IGlueWindow.

Properties

This class has no properties.

Methods

Activate

Activates the window.

Signature:

Sub Activate()

Parameters: None

Return value: None

GetChannelContext

Obtains an instance of GlueContextManager for the io.Connect Channel selected in the window.

Signature:

Function GetChannelContext() As GlueContextManager

Parameters: None

Return value: GlueContextManager or Nothing in case no Channel is selected in the window.

GetChannelSupport

Determines whether the io.Connect Window has Channel support enabled. When Channel support is enabled, a Channel selection box will be available in the windows title bar. See also SetChannelSupport.

Signature:

Function GetChannelSupport() As Boolean

Parameters: None

Return value: Boolean

GetId

Obtains the io.Connect Window identifier. The io.Connect Window identifier is an opaque value and the app shouldn't try to interpret the contents of the value in any way.

Signature:

Function GetId() As String

Parameters: None

Return value: String

Contains the identifier that io.Connect keeps for the registered window.

GetTitle

Obtains the io.Connect Window title (caption). The io.Connect Window title is separate and independent from the the VBA form title. The initial io.Connect Window title will be set to the name with which the app was registered in io.Connect. See also SetTitle.

Signature:

Function GetTitle() As String

Parameters: None

Return value: String

IsVisible

Determines whether the io.Connect Window is visible. See also SetVisible.

Signature:

Function IsVisible() As Boolean

Parameters: None

Return value: Boolean

SetChannelSupport

Enables or disables Channel support for the io.Connect Window. When Channel support is enabled, a Channel selection box will be available in the windows title bar. See also GetChannelSupport.

Signature:

Sub SetChannelSupport(showLink As Boolean)

Parameters:

Return value: None

SetTitle

Sets the title (caption) of the io.Connect Window. See also GetTitle.

Signature:

Sub SetTitle(title As String)

Parameters:

Return value: None

SetVisible

Shows or hides the io.Connect Window. See also IsVisible.

Signature:

Sub SetVisible(visible As Boolean)

Parameters:

Return value: None

Nonapplicable Methods

The following methods aren't intended to be used in VBA:

• Unregister

Events

HandleChannelChanged

The handler for this event is executed when the user changes the Channel from the Channel selection box in the window title bar.

Handler signature:

Sub GlueWindow_HandleChannelChanged(ByVal Window As IGlueWindow, ByVal Channel As IGlueContext, ByVal prevChannelName As String)

Parameters:

HandleChannelData

The handler for this event is executed in two cases:

• when the data in the selected Channel changes;
• after the HandleChannelChanged event, when the user switches to another Channel using the Channel selection box in the title bar.

Handler signature:

Sub GlueWindow_HandleChannelData(ByVal window As IGlueWindow, ByVal channelUpdate As IGlueContextUpdate)

Parameters:

HandleWindowDestroyed

The handler for this event is executed when the io.Connect Window is being destroyed. The purpose for raising this event is to provide an opportunity for the VBA app to gracefully unload the VBA UserForm.

Handler signature:

Sub GlueWindow_HandleWindowDestroyed(ByVal window As IGlueWindow)

Parameters:

HandleWindowEvent

The handler for this event is executed when various events related to the io.Connect Window are fired, e.g. when the window is activated, moved, etc.

Handler signature:

Sub GlueWindow_HandleWindowEvent(ByVal window As IGlueWindow, ByVal eventType As GlueWindowEventType, ByVal eventData As GlueDynamicValue)ndow)

Parameters:

HandleWindowReady

The handler for this event is executed when the io.Connect Window registration has completed.

Handler signature:

Sub GlueWindow_HandleWindowReady(ByVal window As IGlueWindow)

Parameters:

To interact with the io.Connect Window, the app can use either the instance of GlueWindow passed to this event handler, or the instance obtained from RegisterGlueWindow.

GlueWindowSettings

This class is used to store the settings to be used when registering a UserForm as an io.Connect Window.

Properties

StandardButtons

The StandardButtons property specifies which command buttons will be available in the window title bar. A comma-separated list of the following values may be provided:

Methods

This class has no methods.

VBGlueInvocationResult

Instances of this class are returned by io.Connect when an asynchronous method invocation has completed. Interface: IGlueInvocationResult.

Properties

Methods

This class has no methods.

VBGlueStreamSubscriber

This class is used to store information about an io.Connect stream subscriber app. An instance of this class is passed to event handlers of GlueServerStream (see HandleSubscriber and HandleSubscriberLost. Interface: IVBGlueStreamSubscriber.

Properties

This class has no properties.

Methods

Close

Unsubscribes (removes) a subscriber from the stream.

Signature:

Sub Close(data)

Parameters:

Return value: None

GetStream

Gets information about the streaming method to which the app is subscribing.

Signature:

Function GetStream() As VBGlueMethod

Parameters: None

Return value: VBGlueMethod

GetSubscriberInstance

Gets information about the subscriber app instance.

Signature:

Function GetSubscriberInstance() As VBGlueInstance

Parameters: None

Return value: VBGlueInstance

Push

Pushes stream data only to the associated subscriber app instance.

Signature:

Sub Push(data)

Parameters:

Return value: None